**************************************************************************************
	;Header frs File-linken

	IFD	Flag_project
Flag_anim	set 1
	ENDC
	IFND	Flag_anim
Flag_anim	set 0
	ENDC
	IFEQ	Flag_anim
Flag_anim	set 1
	include	Nutz_project
	ELSEIF
**************************************************************************************
*-------------------------------------------------------------------------------------
*-------------	SKY Info Numbers
*-------------------------------------------------------------------------------------
SARROW_LU		=71
SARROW_U		=72
SARROW_RU		=73
SARROW_R		=74
SARROW_RD		=75
SARROW_D		=76
SARROW_LD		=77
SARROW_L		=78
*-------------------------------------------------------------------------------------
CLOUD_FAST	=66
*-------------------------------------------------------------------------------------
FLAG_BLUE_EASY	=64
FLAG_BLUE		=65
*-------------------------------------------------------------------------------------
*----------	ARROWS ARROWS ARROWS ARROWS ARROWS
*-------------------------------------------------------------------------------------
ARROW_L_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_L_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_L_Anim:		dc.w	0
		dc.l	Sky_Obj1_6,0
		dc.w	0
		dc.l	Sky_Obj1_7,0
		dc.w	0
		dc.l	Sky_Obj1_8,0
		dc.w	ENTRY_END
		dc.l	A_L_Anim
*-------------------------------------------------------------------------------------
ARROW_R_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_R_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_R_Anim:		dc.w	1
		dc.l	Sky_Obj1_6,0
		dc.w	1
		dc.l	Sky_Obj1_7,0
		dc.w	1
		dc.l	Sky_Obj1_8,0
		dc.w	ENTRY_END
		dc.l	A_R_Anim
*-------------------------------------------------------------------------------------
ARROW_LU_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_LU_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_LU_Anim:	dc.w	0
		dc.l	Sky_Obj1_9,0
		dc.w	0
		dc.l	Sky_Obj1_10,0
		dc.w	0
		dc.l	Sky_Obj1_11,0
		dc.w	ENTRY_END
		dc.l	A_LU_Anim
*-------------------------------------------------------------------------------------
ARROW_RU_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_RU_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_RU_Anim:	dc.w	1
		dc.l	Sky_Obj1_9,0
		dc.w	1
		dc.l	Sky_Obj1_10,0
		dc.w	1
		dc.l	Sky_Obj1_11,0
		dc.w	ENTRY_END
		dc.l	A_RU_Anim
*-------------------------------------------------------------------------------------
ARROW_RD_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_RD_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_RD_Anim:	dc.w	3
		dc.l	Sky_Obj1_9,0
		dc.w	3
		dc.l	Sky_Obj1_10,0
		dc.w	3
		dc.l	Sky_Obj1_11,0
		dc.w	ENTRY_END
		dc.l	A_RD_Anim
*-------------------------------------------------------------------------------------
ARROW_LD_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_LD_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_LD_Anim:	dc.w	2
		dc.l	Sky_Obj1_9,0
		dc.w	2
		dc.l	Sky_Obj1_10,0
		dc.w	2
		dc.l	Sky_Obj1_11,0
		dc.w	ENTRY_END
		dc.l	A_LD_Anim
*-------------------------------------------------------------------------------------
ARROW_U_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_U_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_U_Anim:		dc.w	0
		dc.l	Sky_Obj1_12,0
		dc.w	0
		dc.l	Sky_Obj1_13,0
		dc.w	0
		dc.l	Sky_Obj1_14,0
		dc.w	ENTRY_END
		dc.l	A_U_Anim
*-------------------------------------------------------------------------------------
ARROW_D_Info:	dc.l	Standard_Arrow
		dc.w	32,32
		dc.l	A_D_Anim
		dc.w	0,6
		dc.b	0,BOB_MID_PRIO
*-------------------------------------------------------------------------------------
A_D_Anim:		dc.w	2
		dc.l	Sky_Obj1_12,0
		dc.w	2
		dc.l	Sky_Obj1_13,0
		dc.w	2
		dc.l	Sky_Obj1_14,0
		dc.w	ENTRY_END
		dc.l	A_D_Anim
*-------------------------------------------------------------------------------------
Standard_Arrow:	*--*>Standard ARROW Routine
		and	#$fff0,Bob_X_Position(a4)
		and	#$fff0,Bob_Y_Position(a4)
		jsr	Standart_BobAnim
		jsr	Test_Bob_Out
		jsr	Show_Arrows
		rts

**************************************************************************************
*-------------------------------------------------------------------------------------
FLAG_BLUE_Info:	dc.l	Standart_AnimF
		dc.w	21,32
		dc.l	Flag_Blue_Anim
		dc.w	0,6
		dc.b	0,BOB_HI_PRIO
*-------------------------------------------------------------------------------------
Standart_AnimF	*--*>StandartAnim for Flags
		move	Bob_Y_Offset(a4),d0
		jsr	Standart_BobAnim
		move	d0,Bob_Y_Offset(a4)
		jsr	Show_Arrows
		rts
*-------------------------------------------------------------------------------------
Flag_Blue_Anim:	dc.w	0
		dc.l	Sky_Obj1_2,0
		dc.w	0
		dc.l	Sky_Obj1_3,0
		dc.w	0
		dc.l	Sky_Obj1_4,0
		dc.w	0
		dc.l	Sky_Obj1_5,0
		dc.w	ENTRY_END
		dc.l	Flag_Blue_Anim

**************************************************************************************
*-------------------------------------------------------------------------------------
*-----------	GATE ROUTINES
*-------------------------------------------------------------------------------------
GATE_BLUE_Info:	dc.l	Init_Blue_Gate_E
		dc.w	36,32
		dc.l	Fly_Anim
		dc.w	0,2
		dc.b	0,BOB_HI_PRIO
*-------------------------------------------------------------------------------------
Fly_Anim:		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,+0
		dc.w	1
		dc.l	Sky_Obj1_0
		dc.w	+0,-2
		dc.w	1
		dc.l	Sky_Obj1_0
		dc.w	+0,-4
		dc.w	1
		dc.l	Sky_Obj1_0
		dc.w	+0,-6
		dc.w	1
		dc.l	Sky_Obj1_0
		dc.w	+0,-7
		dc.w	1
		dc.l	Sky_Obj1_0
		dc.w	+0,-8
		dc.w	1
		dc.l	Sky_Obj1_0
		dc.w	+0,-9
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-9
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-8
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-7
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-6
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-4
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-2
		dc.w	1
		dc.l	Sky_Obj1_1
		dc.w	+0,-1
		dc.w	ENTRY_END
		dc.l	Fly_Anim
*-------------------------------------------------------------------------------------
*-------------------------------------------------------------------------------------
Second_Huhn_Base	=Bob_Koords_Save1
Flag_Base		=Bob_Koords_Save2
Timet_In_Flag	=Bob_Special_1
Huhn_Gem_a2	=Bob_Koords_Save2
Huhn_Gem_Anz	=Bob_Special_1
*-------------------------------------------------------------------------------------
Check_Number	*--*>Count 3erBits to Get Number
		rts
		moveq	#0,d7
		move	Bob_X_Position(a4),d0
		move	Bob_Y_Position(a4),d1
		;jsr	Get_Block_B

.CountLoop	*--BITtest
		move	(a0),d0
		;btst	#ELEVATORBIT,d0
		beq.s	.END_Count
		*--*>rise Number
		addq	#1,d7
		addq	#2,a0
		bra.s	.CountLoop
.END_Count	*--*>Counten fertig d7=ERG
		cmp	#1,d7
		bne.s	.NoClear
		;clr.w	Flown_Gates_Anz(a6)
.NoClear		rts
*-------------------------------------------------------------------------------------
Init_Blue_Gate_E:	*--*>Init Blue Gate
		;jsr	Check_Number
		moveq	#1,d7
		sub	#2*16,Bob_Y_Position(a4)
		move	Flown_Gates_Anz(a6),d0
		addq	#1,d0

		*--*>Init Which Bobs should be entered
		move	#FLAG_BLUE,d3
		move	#FLAG_BLUE_EASY,d4
		*--*>Correct Gate ?
		cmp	d0,d7
		;bne	.NoFlagsInit
		*--*Init Flags
		bsr	Init_Flags
		rts
.NoFlagsInit	*--*>Inkt No Flags
		bsr	NoFlagsInit
		rts
*-------------------------------------------------------------------------------------
*- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Init_Flags	*--*>FLAGS Eintragen
		move.l	a4,a5
		*--get six Entrys
		moveq	#4,d0
		jsr	Get_Entry_Adrs_HI
		tst	d0
		bne	EndBob
		*--*>Get BaseValues for ENEMIES
		lea	ENTRY_ADRS(a6),a0
		move.l	Bob_Entry_Adress(a5),a1
		move	Bob_X_Position(a5),d5
		move	Bob_Y_Position(a5),d6
		move.b	#BOB_FALSE,Bob_Used(a5)
		sub	#3*16+8,d6
		*--Init FLAG UPER
		move	d3,d0
		move	d5,d1
		move	d6,d2
		add	#11,d1
		sub	#8,d2
		move.l	(a0),a4
		jsr	ENTER_BOB
		move.l	a4,a5		;Save Flag Base 
		*--*>Init HUHN Upper
		move	d4,d0
		move	d5,d1
		move	d6,d2
		move.l	4(a0),a4
		jsr	ENTER_BOB
		move.l	a5,Flag_Base(a4)
		add	#8*16,d6
		*--Init FLAG DOWNER
		move	d3,d0
		move	d5,d1
		move	d6,d2
		add	#11,d1
		sub	#8,d2
		move.l	8(a0),a4
		jsr	ENTER_BOB
		move.l	a4,a5		;Save Flag Base 
		*--*>Init HUHN DOWNER
		move	d4,d0
		move	d5,d1
		move	d6,d2
		move.l	12(a0),a4
		jsr	ENTER_BOB
		move.l	a5,Flag_Base(a4)
		move.l	#-1,Second_Huhn_Base(a4)
		*--*>Routines und Base Adr initialisieren
		move.l	4(a0),a5	;first Huhn
		move.l	a4,Second_Huhn_Base(a5)
		move.l	#RoutRts,Bob_Routine(a4)
		move.l	#Control_Huhn,Bob_Routine(a5)
		rts
*- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
NoFlagsInit	*--*>FLAGS Eintragen
		move.l	a4,a5
		*--get six Entrys
		moveq	#2,d0
		jsr	Get_Entry_Adrs_HI
		tst	d0
		bne	EndBob
		*--*>Get BaseValues for ENEMIES
		lea	ENTRY_ADRS(a6),a0
		move.l	Bob_Entry_Adress(a5),a1
		move	Bob_X_Position(a5),d5
		move	Bob_Y_Position(a5),d6
		move.b	#BOB_FALSE,Bob_Used(a5)
		sub	#3*16+8,d6
		*--*>Init HUHN Upper
		move	d4,d0
		move	d5,d1
		move	d6,d2
		move.l	(a0),a4
		jsr	ENTER_BOB
		move.l	#-1,Flag_Base(a4)
		add	#8*16,d6
		*--*>Init HUHN DOWNER
		move	d4,d0
		move	d5,d1
		move	d6,d2
		move.l	4(a0),a4
		jsr	ENTER_BOB
		move.l	#-1,Flag_Base(a4)
		move.l	#-1,Second_Huhn_Base(a4)
		*--*>Routines und Base Adr initialisieren
		move.l	(a0),a5	;first Huhn
		move.l	a4,Second_Huhn_Base(a5)
		move.l	#RoutRts,Bob_Routine(a4)
		move.l	#Control_Huhn_OF,Bob_Routine(a5)
		rts
*- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
EndBob		*--*>NO PLACE for BOBS
		move.l	a5,a4
		jsr	Out_Bob
		rts
*-------------------------------------------------------------------------------------
*-------------------------------------------------------------------------------------
Dead_Huhn		*--*>Get Gems !
		jsr	HANDLE_Enter_Gemsen		
		rts
*-------------------------------------------------------------------------------------
Control_Huhn	*--*>Controlator ohne Flags
		jsr	Test_Bob_Out
		*--*>Test Second OUt
		cmp.b	#BOB_FALSE,Bob_Used(a4)
		bne.s	.NoOutHhner
.OutSystem	move.l	Flag_Base(a4),a5
		move.b	#BOB_FALSE,Bob_Used(a5)
		move.l	Second_Huhn_Base(a4),a4
		move.b	#BOB_FALSE,Bob_Used(a4)
		move.l	Flag_Base(a4),a5
		move.b	#BOB_FALSE,Bob_Used(a5)
		rts
.NoOutHhner	*---*>Animieren & Test TEMET Hit
		jsr	Test_System_Platz
		cmp.l	#Dead_Huhn,Bob_Routine(a4)
		bne.s	.NoOutSystem
		rts
.NoOutSystem	jsr	Test_TEMET_Hit
		jsr	Standart_BobAnim
		move.l	Flag_Base(a4),a5
		move	Bob_Y_Offset(a4),Bob_Y_Offset(a5)
		bsr	Show_Arrows
		*--*>Second Huhn
		move.l	Second_Huhn_Base(a4),a4
		jsr	Test_TEMET_Hit
		jsr	Standart_BobAnim
		move.l	Flag_Base(a4),a5
		move	Bob_Y_Offset(a4),Bob_Y_Offset(a5)
		bsr	Show_Arrows
.NoSecondHuhn	rts
*-------------------------------------------------------------------------------------
Control_Huhn_OF	*--*>Controlator ohne Flags
		jsr	Test_Bob_Out
		*--*>Test Second OUt
		cmp.b	#BOB_FALSE,Bob_Used(a4)
		bne.s	.NoOutHhner
		tst.l	Second_Huhn_Base(a4)
		bmi.s	.NoSecondHuhn
		move.l	Second_Huhn_Base(a4),a4
		move.b	#BOB_FALSE,Bob_Used(a4)
		rts
.NoOutHhner	*---*>Animieren & Test TEMET Hit
		jsr	Test_TEMET_Hit
		jsr	Standart_BobAnim
		bsr	Show_Arrows
		tst.l	Second_Huhn_Base(a4)
		bmi.s	.NoSecondHuhn
		*--*>Second Huhn
		move.l	Second_Huhn_Base(a4),a4
		jsr	Test_TEMET_Hit
		jsr	Standart_BobAnim
		bsr	Show_Arrows
.NoSecondHuhn	rts
*-------------------------------------------------------------------------------------
Test_System_Platz	*--*>Checken ob TIMET in System
		*--*>Test if Temet Passes FLAGS
		lea	WorkRam,a2
		move	Bob_X_Position(a4),d0
		move	Bob_Y_Position(a4),d1
		add	#18,d1
		sub	TEMET_X_Position(a2),d0
		sub	#16,d0
		sub	TEMET_Y_Position(a2),d1
		sub	#16,d1
		*--Test if Y is to far away
		tst	d1
		bpl	.NOTIN
.Temet_Down	*--Temet is down
		neg	d1
		cmp	#7*16,d1
		bhs.s	.NOTIN
		*--Test X
		tst	d0
		bpl.s	.Temet_Left
.Test_Temet_In	*--Test if Temet is in Klappe
		add	#32,d0
		bmi.s	.Temet_Right
		*--Temet is In
		move	TEMET_Dir_X(a2),Timet_In_Flag(a4)
		rts
.Temet_Left	*--Temet is Left
		tst	Timet_In_Flag(a4)
		bpl.s	.NOTIN
		tst	TEMET_Dir_X(a2)
		bmi.s	.DURCHFLOGEN
		bra.s	.NOTIN
		rts
.Temet_Right	*--Temet is Right
		tst	Timet_In_Flag(a4)
		beq.s	.NOTIN
		bmi.s	.NOTIN
		tst	TEMET_Dir_X(a2)
		bpl.s	.DURCHFLOGEN
		bra.s	.NOTIN
		rts
.NOTIN		*--*>Nicht Drin
		clr.w	Timet_In_Flag(a4)
		rts
.DURCHFLOGEN	*--*>Durchgeflogen
		IFEQ	SOUNDFX
		moveq	#11,d0
		jsr	TFMX+16
		ENDC
		;jsr	ENTER_SMOKE_Y
		move.l	#Dead_Huhn,Bob_Routine(a4)
		move.l	Flag_Base(a4),a5
		move.b	#BOB_FALSE,Bob_Used(a5)
		jsr	INIT_Gemsen
		move.l	a4,-(sp)
		move.l	Second_Huhn_Base(a4),a4
		;jsr	ENTER_SMOKE_X
		move.l	#Dead_Huhn,Bob_Routine(a4)
		move.l	Flag_Base(a4),a5
		move.b	#BOB_FALSE,Bob_Used(a5)
		jsr	INIT_Gemsen
		move.l	(sp)+,a4
		addq	#1,Flown_Gates_Anz(a6)
		rts

		;move.l	Second_Huhn_Base(a4),a4
*-------------------------------------------------------------------------------------
INIT_Gemsen	*--*>Gems eintragen
		jsr	Get_Zuffi_d0
		and	#7,d0
		lea	Flugbahn_Tab,a2
		lsl	#3,d0
		add	d0,a2
		move.l	a2,Huhn_Gem_a2(a4)
		move	#3-1,Huhn_Gem_Anz(a4)
		rts
*-------------------------------------------------------------------------------------
HANDLE_Enter_Gemsen	*--*>Choose Gem to Spuck
		jsr	Get_Zuffi_d2
		move.l	Huhn_Gem_a2(a4),a2
		move	#GEMC2,d0
		move.b	#1,d6
		and	#1,d2
		beq.s	.NoNEg
		move	#GEMC1,d0
		move.b	#-1,d6
.NoNEg		jsr	.EnterGem
		move.l	a2,Huhn_Gem_a2(a4)
		subq	#1,Huhn_Gem_Anz(a4)
		bpl.s	.NoOut
		move.b	#BOB_FALSE,Bob_Used(a4)
.NoOut		rts
*- - - - - - - - - - - - - - - - - - - - - - - - - - - -
.EnterGem		*--Enter Gem
		lea	Area_Enter_Vector(a6),a1
		move	Bob_X_Position(a4),d1
		addq	#8,d1
		move	Bob_Y_Position(a4),d2
		subq	#8,d2
		;addq	#8,d2
		move.l	a4,a5
		jsr	Search_Bob_Entry
		tst	d0
		bmi.s	.NoEntry_Found
.Choose_Flug	*--Choose Which Flugbahn
		move.l	Bob_Routine(a4),Extra_Init_Rout(a4)
		move.l	#Extra_Rout_Falling,Bob_Routine(a4)
		move.l	(a2)+,Gem_X_Speed(a4)
		move.l	(a2)+,Gem_Y_Speed(a4)
		move.b	d6,Gem_Which_Col(a4)
.NoEntry_Found	move.l	a5,a4
		rts
*-------------------------------------------------------------------------------------
Flugbahn_Tab	dc.l	$00028000,$fffe0000
		dc.l	$fffd0000,$fffd0000
		dc.l	$00040000,$fffe0000
		dc.l	$fffe0000,$fffb0000
		dc.l	$00020000,$fffc0000
		dc.l	$00000000,$fffb0000
		dc.l	$00018000,$fffe0000
		dc.l	$fffd8000,$fffd0000

		dc.l	$00028000,$ffff0000
		dc.l	$fffd0000,$fffe0000
		dc.l	$00040000,$ffff0000
		dc.l	$fffe0000,$fffb0000
		dc.l	$00020000,$fffd0000
		dc.l	$00000000,$fffc0000
		dc.l	$00018000,$ffff0000
		dc.l	$fffd8000,$fffe0000

**************************************************************************************


**************************************************************************************
*---------------------------------------------------------------------------
Cloud_Info:	dc.l	I_Cloud_Fast
		dc.w	17
		dc.w	48
		dc.l	Cloud_AnimTable1
		dc.w	0,8
		dc.b	0,BOB_HI_PRIO

I_Cloud_Fast	*--*>Init Values for MoverYRout
		move.l	#RoutRts,Mover_Move_Routine(a4)
		move.l	#Mover_Global_Sre,Bob_Routine(a4)
		move.b	#121,Mover_X_Wait_Time(a4)
		*--*>Set Mover to WaterY
		*--*>Init Y Offset
		*--*>Init Wait Times
		clr.b	Mover_Sre_Anim(a4)
		clr.b	Mover_Sre_Blink(a4)
		clr.b	Mover_Sre_Aufl_Flag(a4)
		move.b	#40,Mover_Sre_Time(a4)
		rts
*-------------------------------------------------------------------------------------
*-------------------------------------------------------------------------------------
Mover_Global_Sre	*--*>ANIMATE

		jsr	Standart_BobAnim

		*--*>Test if Sre is still there
		cmp.b	#2,Mover_Sre_Aufl_Flag(a4)
		bne.s	.Platform_STill
		*--*>Test if Blink
		move.b	#3,Mover_Sre_Aufl_Flag(a4)
		move.l	#Cloud_Aufl_Anim,Bob_Next_Anim(a4)
		move	#5,Bob_Anim_Delay_Init(a4)
		move.l	#Explode_Wolke,Bob_Routine(a4)
		IFEQ	SOUNDFX
		moveq	#10,d0
		jsr	TFMX+16
		ENDC
		*--*>TEMET ON then Jump him UP
		tst.b	Mover_TEMET_On(a4)
		beq	.ENDE
		*--*>JUMP TEMET UP
		lea	WorkRam,a2
		subq	#3,TEMET_Y_Position(a2)
		clr.b	Mover_TEMET_On(a4)
		move	#FALLEN,TEMET_Status(a2)
	 	clr.w	TEMET_JumpHight(a2)
		clr.w	TEMET_Speed_Y(a2)
		move.b	#-8,TEMET_Speed_Y(a2)
		clr.w	TEMET_KollisionFlag(a2)
		clr.w	TEMET_New_Calc_Flag(a2)
		bra.s	.ENDE
.NoTEMETON

.Platform_STill	*--*>Test if TEMET is on NOW
		tst.b	Mover_TEMET_On(a4)
		beq.s	.NoAuflInitFlagOn
		tst.b	Mover_Sre_Aufl_Flag(a4)
		bne.s	.NoAuflInitFlagOn
		move.b	#1,Mover_Sre_Aufl_Flag(a4)
.NoAuflInitFlagOn	tst.b	Mover_Sre_Aufl_Flag(a4)
		beq.s	.NoAufTimeDown
		tst.b	Mover_Sre_Time(a4)
		beq.s	.NoAufTimeDown
		subq.b	#1,Mover_Sre_Time(a4)
		bne.s	.NoAufTimeDown
		move.b	#2,Mover_Sre_Aufl_Flag(a4)
.NoAufTimeDown
		*--*>Global Routs for WOLKE
		jsr	Test_Bob_Out
		*--*>Make Movement
		;move.l	Mover_Move_Routine(a4),a0
		;jsr	(a0)

		jsr	Test_Schwank
		*--*>Test Temet on Top
		cmp.b	#3,Mover_Sre_Aufl_Flag(a4)
		beq.s	.ENDE

		move.b	Mover_TEMET_On(a4),d0
		move	d0,-(sp)
		jsr	Test_TEMET_On_Top_S
		move	(sp)+,d0
		*--*>Test if should Init Y Jump
		tst.b	d0
		beq.s	.TEMET_WAS_NOT_ON
.TEMET_WAS_ON	*--Temet war drauf
		tst.b	Mover_TEMET_On(a4)
		bne.s	.Go_Ende
		move	#JUMP_END,Mover_Y_Offset(a4)
		bra.s	.ENDE
.TEMET_WAS_NOT_ON	*--Temet war nicht drauf
		tst.b	Mover_TEMET_On(a4)
		beq.s	.Go_Ende
		move	#JUMP_ANF,Mover_Y_Offset(a4)
.Go_Ende
		*--*>ENDE
.ENDE		bsr	Showdawolge
		rts

Explode_Wolke:	jsr	Standart_BobAnim
		bsr	Showdawolge
		rts

*-------------------------------------------------------------------------------------
Cloud_AnimTable1:	dc.w	0
		dc.l	Sky_Obj2_0
		dc.w	0,0
		dc.w	1
		dc.l	Sky_Obj2_0
		dc.w	0,0
		dc.w	ENTRY_END
		dc.l	Cloud_AnimTable1
*-------------------------------------------------------------------------------------
Cloud_Aufl_Anim:	dc.w	0
		dc.l	Sky_Obj2_1
		dc.w	0,0
		dc.w	0
		dc.l	Sky_Obj2_2
		dc.w	0,0
		dc.w	0
		dc.l	Sky_Obj2_3
		dc.w	0,0
		dc.w	0
		dc.l	Sky_Obj2_4
		dc.w	0,0
		dc.w	END_OUT
*-------------------------------------------------------------------------------------
Schwank_Tab	dc.b	+0,+0
		dc.b	+1,+1,+1,+2,+2,+2,+2,+3,+3,+3,+3,+3,+3
		dc.b	+2,+2,+2,+2,+1,+1,+1,+0,+0,-1,-1,-1,-2,-2,-2,-2
		dc.b	-3,-3,-3,-3,-3,-3,-2,-2,-2,-2,-1,-1,-1
		dc.b	-101
		even
.Schwank_Tab0	dc.b	+2,+4,+6,+8,+10,+12,+13,+14,+15,+15,+16,+16,+16,+17,+17,+17,+17,+17,+17
		dc.b	+16,+16,+16,+15,+15,+14,+14,+13,+13,+12,+12,+11,+11,+11,+10
		dc.b	-100
		even
.Schwank_Tab1	dc.b	+10,+10,+10,+9,+9,+9,+8,+8,+8,+7,+7,+7,+6,+6,+6
		dc.b	+5,+5,+5,+4,+4,+4,+3,+3,+3,+2,+2,+2,+1,+1,+1,+1
		dc.b	+0
		dc.b	-100
		even
*- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
JUMP_ANF=.Schwank_Tab0-Schwank_Tab
JUMP_END=.Schwank_Tab1-Schwank_Tab
JUMP_NO=00
*- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
Test_Schwank	*--*>
		lea	Schwank_Tab,a0
		move	Mover_Y_Offset(a4),d0
		cmp.b	#-101,(a0,d0)
		bne.s	.NpBack
		move	#JUMP_NO,Mover_Y_Offset(a4)
		bra.s	Test_Schwank
.NpBack		move.b	(a0,d0),d1
		ext.w	d1
		move	d1,Bob_Y_Offset(a4)
		cmp.b	#-100,1(a0,d0)
		beq.s	.NoSchwank
		addq	#1,Mover_Y_Offset(a4)
.NoSchwank	*--*>No Schwank
		rts

		include	binary/Sky/Sky_ene2.src
		include	binary/Sky/Sky_ene1.src

**************************************************************************************
*-------------------------------------------------------------------------------------
Show_Arrows	*--*>Show it
		move.w	#Sky_EnemyVRam/32,d3
		move.l	Bob_SigelInfo(a4),a0
		move.w	Bob_FlipStatus(a4),d2
		jsr	Show_Simple_Object
		rts
Showdawolge:	move.w	#Sky_Enemy2VRam/32,d3
		move.l	Bob_SigelInfo(a4),a0
		move.w	Bob_FlipStatus(a4),d2
		jsr	Show_Simple_Object
		rts
*-------------------------------------------------------------------------------------

	ENDC
